Your Bunk : Orbit IO-9

Unladen : On Approach

SPACE TUG BLUES — DEMO
By D. Vincent Baker

For instructions, click:

You're zipped into your bunk in Butterfly's cabin. A soft chime rouses you and the destination alert lights green.

Exits:

Save game as:

Really restart this game?

Display options

font:

font size:

Print room title in scroller:

Always

Landscape only

Never

List objects in scroller

Always

Landscape only

Never

This game was made with gruescript.

game Kite Day in Reign Country &mdash; Demo # Game title
id kiteday # game ID (used to identify cookies; should be unique on your site)
author D. Vincent Baker With Tovey Baker
version 0.0.1
person 2 # 2nd person, i.e. "You are in..."
examine on # if 'on', the verb 'examine' will be implemented by clicking nouns
wait off
conversation on
color statusbar_background c2421e
color statusbar_text feed72
color main_background 003d21
color main_text fff8c2
color main_prompt feed72
color main_text_old a5d35f
color main_prompt_old ffec5c
color instructions_button feed72
color instructions_button_text 003d21
color room_background 002916
color room_text a5d35f
color room_button feed72
color room_button_text 003d21
color conversation_background 00522c
color conversation_text a5d35f
color conversation_button feed72
color conversation_button_text 003d21
color examine_button 002916
color examine_button_text a5d35f
color inventory_background 003d21
color inventory_text a5d35f
color inventory_button feed72
color inventory_button_text 003d21
color inventory_inactive_text 003d21
color save_background 002916
color save_button c2421e
color save_button_text feed72
color page_background 002916
# localize ok_youre_wearing_it { $this.ok_youre_wearing_it }
localize exits &nbsp;
localize actions &nbsp;
localize you_can_also_see You can see:
status { $room.display } | &nbsp; # '|' divides left and right ends of status bar
say You're a Fnimling. You're just a little guy. You're like if a person, but also a rabbit, but also a goat.
say
say You're only so tall. You have soft fur. You have a tail, nubby horns on your forehead, and a skull like a hard helmet. You feel your feelings strongly. You're easy to knock down but hard to hurt.
say 
say You live in Reign Country, and today it's spring...
say
run flykite
run kitefield_countdown

proc flykite
give kitestring

proc kitefield_countdown
pick kitefield.countdown these 8 9 10 10 10 11 11 12 12

# verbose / terse
# rule
# assign $room.desc $room.terse

# verb go
# assign $room.desc $room.verbose
# continue

verb look
display look around
prompt look around
say { $room.verbose }

proc lookmore

verb examine
display look at { $this }
continue

verb examine
has $this a_floren
tag Floren conversation
tag Floren2 conversation
continue

verb examine
is this jumbled_stones
!has glass_bottle exists
say A line of jumbled stones runs along the edge of the kite field. It used to be a stone wall, a long time ago. Someone's left a brown glass bottle among the stones.
bring glass_bottle
tag glass_bottle exists

room holdingspace

proc xfer
run markall
run xferall

proc xferback
run xferwornback
run xfercarriedback

proc markall
all carried
has $this worn
tag $this wasworn

proc xferall
all carried
put $this holdingspace
has $this wasworn

proc xferwornback
all backward in holdingspace
has $this wasworn
wear $this

proc xfercarriedback
all backward in holdingspace
give $this

room kitefield 
prop display Kite Field
prop desc You're in the kite field. { the_wind.1 }
prop terse You're in the kite field. { the_wind.1 }
prop verbose The kite field is a high field on the ridge of a hill. On one side (West) the hillside slopes away steeply to a wide valley of fields, with a little farm far below. On the other side (East) the hillside slopes away more gently, but deeply forested. { the_wind.1 } The sky is gigantic, blue, with skudding clouds and your kites looking tiny so high up.
prop verbose_case1 The kite field is a high field on the ridge of a hill. On one side (West) the hillside slopes away steeply to a wide valley of fields, with a little farm far below. On the other side (East) the hillside slopes away more gently, but deeply forested. { the_wind.1 } The sky is gigantic, blue, with skudding clouds and your kites looking tiny so high up.
prop verbose_case2 The kite field is a high field on the ridge of a hill. On one side (West) the hillside slopes away steeply to a wide valley of fields, with a little farm far below. On the other side (East) the hillside slopes away more gently, but deeply forested. { the_wind.1 } The sky is gigantic, blue, with skudding clouds. Floren's kite bobs and jerks as they reel it in, and yours is dancing and flying wildly over the treetops.
prop verbose_case3 The kite field is a high field on the ridge of a hill. On one side (West) the hillside slopes away steeply to a wide valley of fields, with a little farm far below. On the other side (East) the hillside slopes away more gently, but deeply forested. { the_wind.1 } The sky is gigantic, blue, with skudding clouds. Floren's kite bobs and jerks as they reel it in, but yours is gone.
tags start windy
verbs look

thing kitestring
name kite string
prop display your kite's string
prop desc your kite's string is pulling steadily. At the other end, your kite is soaring above the trees, a yellow diamond carried high by the wind.
prop desc_flying your kite's string is pulling steadily. At the other end, your kite is soaring above the trees, a yellow diamond carried high by the wind.
prop desc_other 
prop kite 0
tags portable

verb drop kitestring
say If you let go of your kite's string, you'll lose your kite forever.

thing your_kite
name your kite
prop display your kite
prop desc Your kite is soaring above the trees, a yellow diamond carried high by the wind.
prop desc_held Your kite is soaring above the trees, a yellow diamond carried high by the wind.
prop desc_lost Your kite is flying and dancing wildly above the trees, a yellow diamond tossed and dashed by the wind.
loc kitefield

thing kitefield_tree
name tree
prop display a giant old maple
prop desc There's a giant old maple at the end of the kite field. It's leafless still, but it has a million tiny hard brick-red buds.
loc kitefield

setverb climb kitefield_tree
!has kitefield_tree climbed

verb climb kitefield_tree
display climb
carried kitestring
say You can't climb the old maple tree while you're flying your kite.

verb climb kitefield_tree
has your_kite lostforever
say You scramble up the giant old maple tree. You think you can see your kite tangled in a treetop in the woods. You think you could find your way there. Maybe you haven't lost your kite forever after all!
tag your_kite landmarked
tag kitefield_tree climbed

verb climb kitefield_tree
say You scramble up the giant old maple tree and watch carefully until your kite crashes into the trees. You can see it tangled in a treetop in the woods. You think you could find your way there.
tag your_kite lostforever
tag your_kite landmarked
tag kitefield_tree climbed

thing jumbled_stones
name jumbled stones
prop display a jumble of stones
prop desc A line of jumbled stones runs along the edge of the kite field. It used to be a stone wall, a long time ago.
loc kitefield

thing glass_bottle
prop name bottle
prop display a brown glass bottle
prop desc A brown glass bottle. It has a wire swing cap and no label. &bullet; The bottle is empty.
tags portable container

thing half_sandwich
prop name sandwich
prop display half a sandwich
prop desc Half a sandwich, cut on the diagonal. Store-bought rye bread, one heel, with butter and sliced olives.
tags portable edible
cverbs eat

verb drop half_sandwich
say When you have good food to eat, you can't just throw it away.

setverb give half_sandwich
is Floren.hunger shared

verb give half_sandwich
display give back
say "No, let's eat together instead," Floren says.

verb eat half_sandwich
say You and Floren both eat your half sandwiches, carefully, with one hand, tending your kites the whole time.
hide half_sandwich
assign Floren.fears hunger2

thing scarf
prop display Floren's scarf
prop desc Floren's scarf, soft, knit, blue and green.
tags portable wearable

verb remove scarf
say You'll give it back to Floren at the end of the day, when you walk each other home.

thing Floren
name Floren
prop display Floren
tags alive nonbinary proper_name a_floren
prop desc Floren is your friend. They have big brown eyes and a curl of light brown hair in front of one ear. Their kite is soaring, a tiny green diamond high above the trees.
prop start_conversation Floren smiles over at you and listens to what you have to say.
prop end_conversation Floren turns their attention back to their kite.
prop windcold 0
prop hunger untold
prop cold ungiven
prop loneliness uncloser
prop kite unasked
prop enemy unasked
prop fears hunger0
prop hunger0 Floren gets a grave look. "Sometimes we don't have enough to eat at my house," they say.
prop hunger1 Floren gets a grave look. "Sometimes we don't have enough to eat at my house either," they say.
prop hunger2 Floren's nervous to say what they're afraid of. Eventually they shrug and look up at their kite. 
tags alive nonbinary proper_name
loc kitefield

setverb tell_Floren hunger
is Floren.hunger untold

setverb tell_Floren loneliness
is Floren.loneliness uncloser

setverb tell_Floren cold
gt Floren.windcold 0
is Floren.cold ungiven

setverb ask_Floren kite
is Floren.kite unasked

setverb ask_Floren fears
!is Floren.hunger shared

setverb ask_Floren the_enemy
is Floren.enemy unasked

verb tell_Floren hunger
display your hunger
say Floren listens thoughtfully, then passes over half of their sandwich.
give half_sandwich
assign Floren.hunger told
assign Floren.fears hunger1

verb tell_Floren loneliness
display your loneliness
say Floren gives you a shy look with their big brown eyes and sides a little closer to you.
assign Floren.loneliness closer

verb tell_Floren cold
display the cold
say Carefully, tending their kite the whole time, Floren passes you their scarf and helps you wrap it around your collar. The tips of their ears turn pink but they don't mind.
wear scarf
assign Floren.cold given

verb ask_Floren kite
display their kite
say Floren laughs out loud. "It's so high, isn't it!"
assign Floren.kite asked

verb ask_Floren fears
display their fears
assign zx Floren.fears
say { Floren.$zx }
assign Floren.hunger shared

verb ask_Floren the_enemy
display the enemy
say Floren glances into the woods. "My mama's brother says we're safe," they say. "Says the enemy has their own problems and won't come here until later spring, if then."
assign Floren.enemy asked

proc startle
run saveconvo
run xfer
say 
assign startled.rightnow yes
goto startled

proc saveconvo
is conversation Floren
assign Floren2.inconvo yes

room startled At that moment, something startles you. What?
prop display Kite Field
prop face You look and look but there's no face in the woods now.
prop noise You look all around but there's no one here but Floren and all's quiet now.
prop feeling You look all around but there's no one here but Floren. The feeling's gone.
prop creature You look and look but you can't see the creature in the woods now. It could still be there.

setverb face intransitive
at startled
is startled.rightnow yes

setverb noise intransitive
at startled
is startled.rightnow yes

setverb feeling intransitive
at startled
is startled.rightnow yes

setverb creature intransitive
at startled
is startled.rightnow yes

verb face
display a face
prompt a face
assign startled.bywhat face
write startled.lookat look again
say Someone is staring at you from the edge of the forest. A face you ... recognize? A face like a mask of dread, empty-eyed, cold-hearted, cruel.
say 
say You're so frightened that you let go of your kite's string. Your kite leaps and flies wildly away.
run backfrom_startled

verb noise
display a noise
prompt a noise
assign startled.bywhat noise
write startled.lookat spin around
say Someone laughs and screams behind you. It's the sound of ice breaking beneath your feet and you know you'll drown.
say 
say You're so frightened that you let go of your kite's string. Your kite leaps and flies wildly away.
run backfrom_startled

verb feeling
display a feeling
prompt a feeling
assign startled.bywhat feeling
write startled.lookat spin around
say It feels like someone seizes hold of you from behind with hands like cold stone. You can barely breathe.
say 
say You're so frightened that you let go of your kite's string. Your kite leaps and flies wildly away.
run backfrom_startled

verb creature
display a creature
prompt a creature
assign startled.bywhat creature
write startled.lookat look again
say You see a creature in the trees in the valley. It's moving from tree to tree without touching the ground. It's like a wolf, and like a moose, with broken bones for antlers and exposed meat-tearing teeth. It can see you.
say 
say You're so frightened that you let go of your kite's string. Your kite leaps and flies wildly away.
run backfrom_startled

proc backfrom_startled
hide kitestring
assign kitefield.verbose kitefield.verbose_case2
assign your_kite.desc your_kite.desc_lost
assign startled.desc kitefield.desc
assign startled.verbose kitefield.verbose
bring Floren2
bring your_kite
bring kitefield_tree
bring jumbled_stones
assign startled.rightnow no
assign startled.checked no
pick startled.countdown these 4 5 5 5 6 6
assign startled.screamdown startled.countdown
add startled.screamdown -3
run xferback
say 
say Floren doesn't know what happened, but starts reeling in their kite, in case you need help.
is Floren2.inconvo yes
# assign conversation Floren2

setverb scream intransitive
at startled
is startled.rightnow no
gt startled.countdown startled.screamdown

setverb lookat intransitive
at startled
is startled.rightnow no
is startled.checked no

setverb look intransitive
at startled
is startled.rightnow no
is startled.checked yes

setverb chase intransitive
at startled
is startled.rightnow no
!has your_kite lostforever

setverb lookfor intransitive
at startled
is startled.rightnow no
has your_kite lostforever
!has your_kite landmarked

setverb cry intransitive
at startled
is startled.rightnow no
has your_kite lostforever
!has your_kite landmarked

setverb find intransitive
at startled
has your_kite landmarked

verb scream
say You scream. "What! What is it!" Floren says.
assign conversation Floren2

verb chase
display chase your kite
say You race down into the woods after your kite. Floren will follow as soon as they can.
say 
say This is the end of the demo. Thank you for playing!
say 
die The End
# say This is the limit of the demo. In the full game, this action will take you into danger in the woods &mdash; but meanwhile, please enjoy the demo's ending!

verb lookat
display { startled.lookat }
assign cf startled.bywhat
say { startled.$cf }
assign startled.checked yes

verb lookfor
display look for your kite
say It's no use. You can look and look, you'll never be able to see from here where your kite fell.

verb cry
say Fnimlings feel their feelings strongly. You start to cry.
say 
say Floren finishes getting their kite down and comes over to you. They put their arm around your shoulders.
say 
say In a little while they'll offer to make a new kite with you, or if you want you can share theirs for the rest of the day. For now, this is okay.
say 
say This is the end of the game. Thank you for playing!
say 
die The End

verb find
display go find your kite
say You wait for Floren to finish bringing down their kite, then you set off together into the woods.
say 
say This is the end of the demo. Thank you for playing!
say 
die The End

thing Floren2
name Floren
prop display Floren
tags alive nonbinary proper_name a_floren
prop desc Floren is reeling in their kite, quickly, hand over hand. They keep glancing over at you with big concerned eyes.
prop help unasked
prop startle untold
prop dontknow untold

setverb say_Floren2 help
is Floren2.help unasked

setverb ask_Floren2 face
is Floren2.startle untold
is startled.bywhat face

setverb ask_Floren2 noise
is Floren2.startle untold
is startled.bywhat noise

setverb ask_Floren2 feeling
is Floren2.startle untold
is startled.bywhat feeling

setverb ask_Floren2 creature
is Floren2.startle untold
is startled.bywhat creature

setverb tell_Floren2 face
is Floren2.startle untold
is startled.bywhat face

setverb tell_Floren2 noise
is Floren2.startle untold
is startled.bywhat noise

setverb tell_Floren2 feeling
is Floren2.startle untold
is startled.bywhat feeling

setverb tell_Floren2 creature
is Floren2.startle untold
is startled.bywhat creature

setverb say_Floren2 dontknow
is Floren2.startle told
is Floren2.dontknow untold

verb say_Floren2 help
display "help me!"
assign Floren2.help asked
say Floren says, "I've got to get my kite down! You go chase your kite, I'll follow in a second!"

verb ask_Floren2 face
display the face
assign Floren2.startle told
say "I didn't see it," Floren says. "Who was it? Are they still there?"
say 
say Floren reels their kite in more quickly still.

verb ask_Floren2 noise
display the noise
assign Floren2.startle told
say "I didn't hear it," Floren says. "What was it? Are you okay?"

verb ask_Floren2 feeling
display the feeling
assign Floren2.startle told
say "That's horrible," Floren says. "What was it? Are you okay?"

verb ask_Floren2 creature
display the creature
assign Floren2.startle told
say "I didn't see it," Floren says. "What was it? Is it still there?"
say 
say Floren reels their kite in more quickly still.

verb tell_Floren2 face
display the face
assign Floren2.startle told
say Floren listens, their eyes getting wider and wider. They reel their kite in more quickly still. "Who was it?" they say.

verb tell_Floren2 noise
display the noise
assign Floren2.startle told
say Floren listens, their eyes worried. "I didn't hear it," they say. "What do you think it was?"

verb tell_Floren2 feeling
display the feeling
assign Floren2.startle told
say Floren listens, their eyes worried. "What do you think it was?" they say.

verb tell_Floren2 creature
display the creature
assign Floren2.startle told
say Floren listens, their eyes getting wider and wider. They reel their kite in more quickly still. "What do you think it was?" they say.

verb say_Floren2 dontknow
display "I don't know!"
assign Floren2.dontknow told
say Floren wants you to be okay, but doesn't know how to help. They keep reeling their kite in.

proc lose_kite
say 
say Your kite crashes into the trees and you lose sight of it. You've lost it forever.
tag your_kite lostforever
assign startled.verbose startled.verbose_case3

thing the_wind
prop blows none
prop 1 The spring wind blows up the hill from the West, cold and steady.
prop 2 The wind eases for a moment, then picks back up.
prop 3 The wind gusts up behind you. It smells fresh and icy, and makes your ears chill and your eyes water.
prop 4 With a roar the wind rushes up the hill behind you, battering and biting cold.
prop 3scarf The wind gusts up behind you. It smells fresh and icy, and makes you glad for Floren's scarf.
prop 4kite With a roar the wind rushes up the hill behind you, battering and biting cold. Your kite leaps and tries to pull its string from your hand.

proc wind_blows
pick zz these 0 0 0 0 0 2 3 3 3 4 4
assign the_wind.blows none
gt $zz 0
assign the_wind.blows the_wind.$zz
gt $zz 2
assign Floren.windcold 1
run wind_scarf
gt $zz 3
run wind_kite

proc wind_scarf
has scarf worn
assign the_wind.blows the_wind.3scarf

proc wind_kite
carried kitestring
assign the_wind.blows the_wind.4kite

rule
taghere windy
run wind_blows
!eq the_wind.blows none
say { the_wind.blows }

rule
at kitefield
gt kitefield.countdown 0
add kitefield.countdown -1
lt kitefield.countdown 1
run startle

rule
at startled
gt startled.countdown 0
add startled.countdown -1
lt startled.countdown 1
run lose_kite

verb go
goto $room.dir.$direction
# Dodges the default 'OK' go response